Level5 VBA|クエスト5

セルから取得した値や、入力してもらった内容を一時保存したい!
次のコードでは、A1セルの値をB1セルへ直接転記しています。
Range("B1").Value = Range("A1").Value
しかし、セルから取得した値をすぐに転記するのではなく、一時的に保存してから別の処理で使いたい場合もあります。
VBAでは、文字列や数値などを一時的に保存する場所として変数を使用します。
Dim 商品名 As String
商品名 = Range("A1").Value
MsgBox 商品名
このコードでは、A1セルから取得した値を「商品名」という変数へ保存し、その内容をメッセージボックスに表示しています。
この記事では、変数とデータ型の基本、Dimによる宣言、変数への代入方法を解説します。
さらに、InputBoxで入力を受け付け、MsgBoxで結果を表示する基本的な処理も確認しましょう。
変数を宣言して値を一時的に保存し、InputBoxやMsgBoxを使って値を受け渡せるようになりましょう。
VBAの変数とは値を一時的に保存する場所
変数とは、文字列や数値などを一時的に保存しておく場所です。
たとえば、商品名を保存する箱を用意するイメージで考えてみましょう。
Dim 商品名 As String
このコードでは、「商品名」という名前の変数を用意しています。
用意した変数には、次のように値を代入できます。
商品名 = "りんご"
これで、商品名という変数に「りんご」が保存されます。
変数に保存した値は、その後の処理で繰り返し使用できます。
MsgBox 商品名
このコードを実行すると、メッセージボックスに「りんご」と表示されます。
変数を使う理由
セルから取得した値をそのまま別のセルへ転記するだけなら、変数を使わない方法もあります。
Range("B1").Value = Range("A1").Value
一方、取得した値を複数の処理で使用する場合は、変数へ保存するとコードを読みやすくできます。
Dim 商品名 As String
商品名 = Range("A1").Value
Range("B1").Value = 商品名
MsgBox 商品名
このコードでは、A1セルの値を「商品名」という変数へ保存しています。
その後、保存した商品名をB1セルへ入力し、メッセージボックスにも表示しています。
変数名を見るだけで保存されている内容を想像できるため、コードの目的も判断しやすくなります。
Dimで変数を宣言する
VBAで変数を用意するときは、Dimを使って変数を宣言します。
基本形は次のとおりです。
Dim 変数名 As データ型
たとえば、商品名を保存する変数は次のように宣言できます。
Dim 商品名 As String
それぞれの役割は次のとおりです。
Dim:変数を用意する命令商品名:変数の名前As:変数名とデータ型をつなぐString:文字列を保存するデータ型
このコードは、「商品名という名前で、文字列を保存できる変数を用意する」と読めます。
基本的には、変数を使用するマクロの中で宣言します。
VBAコードは上から順番に実行されるため、変数を使用する処理より前に宣言しておきましょう。
変数名を付けるときの基本ルール
変数名は自由に付けられますが、いくつかルールがあります。
変数名の先頭に数字は使用できない
次の変数名は使用できません。
Dim 1商品目 As String
数字を含める場合は、先頭以外に配置します。
Dim 商品1 As String
変数名に使用できない記号がある
変数名にスペースやピリオドなどは使用できません。
次のような名前は避けましょう。
Dim 商品 名 As String
単語を区切りたい場合は、スペースを入れずに記述します。
Dim 商品名 As String
VBAで決められた命令は変数名にしない
SubやRangeなど、VBAですでに役割が決められている単語は、変数名として使用できない場合があります。
保存する内容が分かる名前を付ける
次のような短い変数名でもコードを実行できる場合があります。
Dim a As String
しかし、aだけでは何が保存されているのか判断できません。
Dim 商品名 As String
保存する内容が分かる変数名を付けると、後からコードを読み返したときにも処理を理解しやすくなります。
データ型は変数へ保存する値の種類
変数の宣言で使用するStringやLongなどを、データ型と呼びます。
データ型は、その変数へどのような値を保存するのかを表します。
Dim 商品名 As String
このコードでは、商品名を文字列として保存するため、Stringを指定しています。
| データ型 | 保存する内容 | 宣言例 |
|---|---|---|
String | 文字列 | Dim 商品名 As String |
Long | 整数 | Dim 最終行 As Long |
Double | 小数を含む数値 | Dim 売上金額 As Double |
Date | 日付や時刻 | Dim 売上日 As Date |
Boolean | TrueまたはFalse | Dim 完了判定 As Boolean |
Variant | 複数の種類の値 | Dim 入力内容 As Variant |
Workbook | 1つのブック | Dim 転記先 As Workbook |
Worksheet | 1枚のワークシート | Dim 転記元 As Worksheet |
Range | セル・セル範囲 | Dim 対象範囲 As Range |
これらをすべて暗記する必要はありません。
まずは、文字列を保存するString、整数を保存するLong、小数を含む数値を保存するDoubleの違いを確認しましょう。
Stringは文字列を保存する
Stringは、文章や商品名などの文字列を保存するデータ型です。
Dim 商品名 As String
商品名 = "りんご"
文字列を直接代入するときは、値をダブルクォーテーションで囲みます。
Longは整数を保存する
Longは、行番号や件数など、整数を保存するときに使用します。
Dim 処理件数 As Long
処理件数 = 100
数値は、通常、ダブルクォーテーションで囲みません。
Level5では、データが入力されている最後の行番号や、繰り返し処理の回数を保存する変数としてLongを使用することがあります。
Doubleは小数を含む数値を保存する
Doubleは、小数を含む数値を保存するときに使用します。
Dim 売上金額 As Double
売上金額 = 1250.5
整数も保存できますが、小数を扱う可能性がある金額や計算結果などに使用します。
Variantは複数の種類の値を保存できる
Variantは、文字列や数値など、さまざまな種類の値を保存できるデータ型です。
Dim 入力内容 As Variant
便利な一方で、変数へ何が保存されているのか判断しにくくなることがあります。
保存する値の種類が決まっている場合は、StringやLongなど、目的に合ったデータ型を指定するのが基本です。
数値ならLongやDouble、文字列ならStringのように、変数へ保存する内容に合ったデータ型を指定しましょう。
データ型に合わない値を代入すると、自動的に変換される場合もありますが、変換できない値ではエラーが発生します。
変数へ値を代入する
変数へ値を保存することを、代入と呼びます。
文字列を代入するコードは、次のとおりです。
Dim 商品名 As String
商品名 = "りんご"
数値を代入する場合は、次のように記述します。
Dim 処理件数 As Long
処理件数 = 100
セルの値を変数へ代入することもできます。
Dim 商品名 As String
商品名 = Range("A1").Value
このコードでは、A1セルの値を取得して、商品名という変数へ保存しています。
代入では、=の右側にある値が左側の変数へ渡されます。
- 左側:値を保存する変数
- 右側:変数へ保存する値
「=」を「←」と考えましょう。
オブジェクトを変数へ代入するときはSetを使う
- 文字列や数値を代入する:
変数名 = 値 - オブジェクトを代入する:
Set 変数名 = オブジェクト
文字列や数値を変数へ代入するときは、通常の=を使用します。
Dim 商品名 As String
商品名 = "りんご"
一方、Workbook、Worksheet、Rangeなどのオブジェクトを変数へ代入するときは、Setを使用します。
Dim 転記元 As Worksheet
Set 転記元 = Worksheets("売上表")
このコードでは、「売上表」シートを転記元という変数へ代入しています。
セルやセル範囲を変数へ代入する場合も、Setが必要です。
Dim 対象範囲 As Range
Set 対象範囲 = Range("A2:A10")
変数へ代入した後は、変数名を使って対象を操作できます。
対象範囲.ClearContents
このコードでは、対象範囲に保存されているA2セルからA10セルまでの内容を削除します。
Setの詳しい仕組みを暗記する必要はありません。ブック、ワークシート、セル範囲を変数へ入れるコードでは、Setが付くと覚えておきましょう。
InputBoxで入力を受け付ける
InputBoxを使用すると、マクロの実行中に入力欄を表示できます。
入力された内容は、変数へ保存できます。
Dim 商品名 As String
商品名 = InputBox("商品名を入力してください")
このコードを実行すると、「商品名を入力してください」と表示された入力画面が開きます。
入力された内容は、商品名という変数へ代入されます。
InputBox:入力画面を表示する"商品名を入力してください":入力画面に表示する案内商品名 =:入力された内容を商品名へ保存する
通常のInputBoxで入力された内容は、基本的に文字列として受け取ります。
そのため、基本例ではString型の変数へ保存します。
InputBoxで入力された内容をセルへ入力する
変数へ保存した内容は、セルへ入力できます。
Sub 商品名を入力する()
Dim 商品名 As String
商品名 = InputBox("商品名を入力してください")
Range("A1").Value = 商品名
End Sub
処理の順番は、次のとおりです。
- 商品名という変数を用意する
InputBoxで商品名の入力を受け付ける- 入力された内容を変数へ保存する
- 変数の内容をA1セルへ入力する
InputBoxで[キャンセル]を選択した場合や、何も入力せずに[OK]を選択した場合は、空の文字列""が返されます。キャンセル時に処理を中止する方法は、条件分岐を学ぶクエストで扱います。
MsgBoxでメッセージを表示する
MsgBoxを使用すると、メッセージボックスを表示できます。
MsgBox "処理が完了しました"
このコードを実行すると、「処理が完了しました」と表示されます。
固定された文章だけでなく、変数に保存されている内容も表示できます。
Dim 商品名 As String
商品名 = "りんご"
MsgBox 商品名
この場合は、メッセージボックスに「りんご」と表示されます。
文字列と変数を組み合わせて表示する
固定された文章と変数を組み合わせる場合は、&でつなぎます。
MsgBox 商品名 & "を入力しました"
商品名に「りんご」が保存されている場合、次のように表示されます。
りんごを入力しました
&は、文字列と文字列を結合する記号です。
MsgBox "商品名は「" & 商品名 & "」です"
商品名に「りんご」が保存されている場合は、次のように表示されます。
商品名は「りんご」です
InputBox・変数・Range・MsgBoxを組み合わせる
ここまでに学んだ内容を組み合わせてみましょう。
Sub 商品名を登録する()
Dim 商品名 As String
商品名 = InputBox("商品名を入力してください")
Range("A1").Value = 商品名
MsgBox 商品名 & "をA1セルへ入力しました"
End Sub
このマクロでは、次の処理を上から順番に実行します。
Dimで商品名という変数を用意するInputBoxで商品名の入力を受け付ける- 入力された内容を商品名へ保存する
- 商品名をA1セルへ入力する
- 入力した内容を
MsgBoxで知らせる
コードを「何を・どうする」で読むと、それぞれの役割を判断できます。
商品名 = InputBox("商品名を入力してください")
InputBox:商品名を入力してもらう商品名 =:入力された内容を変数へ保存する
Range("A1").Value = 商品名
Range("A1").Value:A1セルの値を= 商品名:変数に保存されている内容にする
MsgBox 商品名 & "をA1セルへ入力しました"
MsgBox:メッセージを表示する商品名 & "をA1セルへ入力しました":表示する内容
変数を使うことで、InputBoxから受け取った値を、セルへの入力や結果表示など複数の処理へ渡せます。
まとめ|変数へ値を保存して処理に利用しよう
変数は、文字列や数値などを一時的に保存する場所です。
変数を用意するときは、Dimで変数名とデータ型を宣言します。
- 変数は値を一時的に保存する場所
Dim 変数名 As データ型で変数を宣言するStringは文字列、Longは整数、Doubleは小数を含む数値変数名 = 値で文字列や数値を代入する- オブジェクトを変数へ代入するときは
Setを使用する InputBoxで入力を受け付けられるMsgBoxで文章や変数の内容を表示できる- 文字列や変数は
&でつなげられる
次のクエストへ
今回は、文字列や数値を変数へ保存し、InputBox・Range・MsgBoxへ値を受け渡す方法を学びました。
次のクエストでは、If文を使って条件に応じて処理を変える方法を学びます。
InputBoxへ何も入力されなかった場合に処理を中止するなど、今回覚えた変数と条件分岐を組み合わせてみましょう。
Level5の学習順序を確認したい方は、Level5攻略フローをご覧ください。





コメント